Is there a way to direct the key() function back to the
principal document while the context node is located in
another document?

In XSLT 2.0, use the third argument of key() to tell it which document
to search. In 1.0, you need to change context to that document, which
you can do using xsl:for-each.

Michael Kay

Thanks a lot! So the solution involving the documents given in my
original post goes like this:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:variable name="principal-doc" select="/"/>
 <xsl:key name="chnam" match="Chnl" use="@ID"/>
 <xsl:template match="/">
  <Urmel>
   <xsl:for-each select="document('s.xml')//Channel">
    <xsl:variable name="cur" select="."/>
    <xsl:for-each select="$principal-doc"><!-- change context -->
     <p><xsl:value-of select="key('chnam', $cur)"/> this works</p>
    </xsl:for-each>
    <p><xsl:value-of select="key('chnam', $cur)"/>this doesn't</p>
   </xsl:for-each>
  </Urmel>
 </xsl:template>
</xsl:stylesheet>