On Wed, Jul 11, 2001 at 06:49:55PM -0400, by way of B. Tommie Usdin wrote:
> Hi Folks!,
>         I am workin on simple xslt and want to make it look good (I want to
> make it short! lot of xsl:when statements)


Remember to work *with* the template matching rules, not *against* them:

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
  <xsl:output method="xml" indent="yes"/>

  <!-- Ignore these tags in regular processing -->
  <xsl:template match="id | eventName | applicationName | originator | 
		       variable | timestamp | typeid"/>

  <!-- copy all other attributes as '<dataset>...</dataset>' -->
  <xsl:template match="*">
   <dataset>
    <tag> <xsl:value-of select="name()"/> </tag>
    <value> <xsl:value-of select="."/> </value>
   </dataset>
  </xsl:template>

  <xsl:template match="request">
    <xsl:copy>

     <!-- Convert to attributes -->
     <xsl:for-each select="id | eventName | applicationName | originator | 
				variable | timestamp | typeid">
      <xsl:attribute name="{name()}">
       <xsl:value-of select="."/>
      </xsl:attribute>
     </xsl:for-each>

     <!-- Do everything else -->
     <xsl:apply-templates select="*"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>


Z.


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list