>-----Original Message-----
>From: Sanjay Saxena [mailto:ssaxena@xxxxxxxxxxxxx]
  
>Thanks a lot. However, this does not work. 

The following, which is essentially equivalent to Sanjay's posting, does
work with SAXON.
Mike Kay

Stylesheet:
=============================================================
<xsl:transform
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 version="1.0"
>
<xsl:template match="/">
    <xsl:apply-templates select="/FORMS/CONTAINERS"/>
</xsl:template>
<xsl:template match="/FORMS/CONTAINERS"> 
    <xsl:for-each select="CONTAINER"> 

        <xsl:copy-of select="//*[name(.)=current()/PRE_HTML]" /> 
        <xsl:value-of select="TITLE"/>
        <xsl:comment>Do some more things here</xsl:comment>

        <xsl:copy-of select="//*[name(.)=current()/POST_HTML]" /> 

    </xsl:for-each> 
</xsl:template> 
</xsl:transform>
================================================================
Source document:
================================================================
<FORMS> 
    <CONTAINERS> 
        <CONTAINER> 
            <PRE_HTML>DEPT_PREHTML</PRE_HTML> 
            <TITLE>Departments</TITLE> 
            <POST_HTML>DEPT_POSTHTML</POST_HTML> 
        </CONTAINER> 

        <CONTAINER> 
            <PRE_HTML>EMP_PREHTML</PRE_HTML> 
            <TITLE>Employees</TITLE> 
            <POST_HTML>EMP_POSTHTML</POST_HTML> 
        </CONTAINER> 
    </CONTAINERS> 

    <DEPT_PREHTML> 
        <!-- Well-formed HTML. --> 
        <DIV id="Layer1" style="position: absolute"> 
            <IMG src="/images/edu.gif" width="917" 
                 height="104"/> 
        </DIV> 
    </DEPT_PREHTML> 

    <DEPT_POSTHTML> 
        <P>DEPT_POSTHTML: Some more well-formed HTML. </P>
    </DEPT_POSTHTML> 

    <EMP_PREHTML> 
        <P>EMP_PREHTML: Some more well-formed HTML. </P>
    </EMP_PREHTML> 

    <EMP_POSTHTML> 
        <P>EMP_POSTHTML: Some more well-formed HTML. </P>
    </EMP_POSTHTML> 
</FORMS> 
==============================================================
Output:
===============================================================
<?xml version="1.0" encoding="utf-8" ?>
<DEPT_PREHTML> 
        <!-- Well-formed HTML. --> 
        <DIV id="Layer1" style="position: absolute"> 
            <IMG src="/images/edu.gif" width="917" height="104"></IMG> 
        </DIV> 
    </DEPT_PREHTML>Departments<!--Do some more things here--><DEPT_POSTHTML>

        <P>DEPT_POSTHTML: Some more well-formed HTML. </P>
    </DEPT_POSTHTML><EMP_PREHTML> 
        <P>EMP_PREHTML: Some more well-formed HTML. </P>
    </EMP_PREHTML>Employees<!--Do some more things here--><EMP_POSTHTML> 
        <P>EMP_POSTHTML: Some more well-formed HTML. </P>
    </EMP_POSTHTML>
=================================================================


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list